[1] turtleDoc ::= (statement)*
[2] statement ::= (directive '.') | (triples '.')
[3] directive ::= prefixID | base
[4] prefixID ::= '@prefix' PNAME_NS IRIREF
[5] base ::= '@base' IRIREF
[6] triples ::= (subject predicateObjectList) | (blankNodePropertyList (predicateObjectList)?)
[7] predicateObjectList ::= verb objectList (';' verb objectList)* (';')?
[8] objectList ::= object (',' object)*
[9] verb ::= predicate | 'a'
[10] subject ::= iri | blank
[11] predicate ::= iri
[12] object ::= iri | blank | literal
[13] literal ::= RDFLiteral | NumericLiteral | BooleanLiteral
[14] blank ::= BlankNode | blankNodePropertyList | collection
[15] blankNodePropertyList ::= '[' predicateObjectList ']'
[16] collection ::= '(' (object)* ')'
[60s] RDFLiteral ::= String (LANGTAG | ('^^' iri))?
[61s] NumericLiteral ::= NumericLiteralUnsigned | NumericLiteralPositive | NumericLiteralNegative
[62s] NumericLiteralUnsigned ::= INTEGER | DECIMAL | DOUBLE
[63s] NumericLiteralPositive ::= INTEGER_POSITIVE | DECIMAL_POSITIVE | DOUBLE_POSITIVE
[64s] NumericLiteralNegative ::= INTEGER_NEGATIVE | DECIMAL_NEGATIVE | DOUBLE_NEGATIVE
[65s] BooleanLiteral ::= 'true' | 'false'
[66s] String ::= STRING_LITERAL1 | STRING_LITERAL2 | STRING_LITERAL_LONG1 | STRING_LITERAL_LONG2
[67s] iri ::= IRIREF | PrefixedName
[68s] PrefixedName ::= PNAME_LN | PNAME_NS
[69s] BlankNode ::= BLANK_NODE_LABEL | ANON
[132s] IRIREF ::= '<' ([^#x00-#x20<>\"{}|^`\\] | UCHAR)* '>'
[133s] PNAME_NS ::= (PN_PREFIX)? ':'
[134s] PNAME_LN ::= PNAME_NS PN_LOCAL
[135s] BLANK_NODE_LABEL ::= '_:' PN_CHARS_U | [0-9] ((PN_CHARS | '.')* PN_CHARS)?
[19] LANGTAG ::= '@' ([a-zA-Z])+ ('-' ([a-zA-Z0-9])+)*
[20] INTEGER ::= ([+-])? ([0-9])+
[21] DECIMAL ::= (([+-])? ([0-9])+ '.' ([0-9])+) | ('.' ([0-9])+)
[22] DOUBLE ::= (([+-])? ([0-9])+ '.' ([0-9])+ EXPONENT) | ('.' ([0-9])+ EXPONENT) | (([0-9])+ EXPONENT)
[148s] EXPONENT ::= [eE] ([+-])? ([0-9])+
[149s] STRING_LITERAL1 ::= '"' ([^#x27#x5C#xA#xD] | ECHAR | UCHAR)* '"'
[150s] STRING_LITERAL2 ::= "'" ([^#x22#x5C#xA#xD] | ECHAR | UCHAR)* "'"
[151s] STRING_LITERAL_LONG1 ::= "'''" (("'" | "''")? [^'\] | ECHAR | UCHAR)* "'''"
[152s] STRING_LITERAL_LONG2 ::= '"""' (('"' | '""')? [^"\] | ECHAR | UCHAR)* '"""'
[19] UCHAR ::= ('\u' HEX HEX HEX HEX) | ('\U' HEX HEX HEX HEX HEX HEX HEX HEX)
[153s] ECHAR ::= '\' [tbnrf\"']
[154s] NIL ::= '(' (WS)* ')'
[155s] WS ::= #x20 | #x9 | #xD | #xA
[156s] ANON ::= '[' (WS)* ']'
[157s] PN_CHARS_BASE ::= [A-Z] | [a-z] | [#00C0-#00D6] | [#00D8-#00F6] | [#00F8-#02FF] | [#0370-#037D] | [#037F-#1FFF] | [#200C-#200D] | [#2070-#218F] | [#2C00-#2FEF] | [#3001-#D7FF] | [#F900-#FDCF] | [#FDF0-#FFFD] | [#10000-#EFFFF]
[158s] PN_CHARS_U ::= PN_CHARS_BASE | '_' | ':'
[160s] PN_CHARS ::= PN_CHARS_U | '-' | [0-9] | #00B7 | [#0300-#036F] | [#203F-#2040]
[161s] PN_PREFIX ::= PN_CHARS_BASE ((PN_CHARS | '.')* PN_CHARS)?
[162s] PN_LOCAL ::= PN_CHARS_U | [0-9] | PLX ((PN_CHARS | '.' | PLX)* PN_CHARS | PLX)?
[163s] PLX ::= PERCENT | PN_LOCAL_ESC
[164s] PERCENT ::= '%' HEX HEX
[165s] HEX ::= [0-9] | [A-F] | [a-f]
[166s] PN_LOCAL_ESC ::= '\' '_' | '~' | '.' | '-' | '!' | '$' | '&' | "'" | '(' | ')' | '*' | '+' | ',' | ';' | '=' | '/' | '?' | '#' | '@' | '%'